Simple - fibration

Copyright © 2003-2010  DigiArea Group . All rights reserved.

Description:
Kerr black hole   is 4-dimentional Lorentz manifold M with zero Ricci curvature   and group    as a subgroup of the manifold isometry group. In this worksheet we construct riemannian submersion :  where  /  is the corresponding base and  is the fiber. The submersion is  fibration:  where  is open submanifold of M (  is just union of  principal orbits).   

Kerr black hole

First of all we load atlas package:

restart:
with(atlas):

Total space

Declare total space of the submersion:
Domain(M);

Declare constants  and :
Constants(rg,a);

Declare vectors:
Vectors(E[i],X,Y,Z);

Declare forms:
Forms(e[j]=1);

Declare coframe:
Coframe(e[1]=d(t),e[2]=d(r),e[3]=d(theta),e[4]=d(phi));

Declare frame vectors:
Frame(E[i]);

For Kerr metric we use well known aliases :

alias(Delta=r^2-rg*r+a^2,rho=r^2+a^2-a^2*sin(theta)^2, -rho=-r^2-a^2+a^2*sin(theta)^2):

Now we declare Kerr metric:

Metric(g=(Delta-a^2*sin(theta)^2)/rho*d(t)&.d(t)+a*sin(theta)^2*(r^2+a^2-Delta)/rho
*(d(t)&.d(phi)+d(phi)&.d(t))-rho/Delta*d(r)&.d(r)-rho*d(theta)&.d(theta)
+((a^2*sin(theta)^2*Delta)-(r^2+a^2)^2)*sin(theta)^2/rho*d(phi)&.d(phi));

Connection calculation:
Connection(omega);

Base space

Declare base space:
Domain(B);

Declare forms:
Forms(u[k]=1);

Declare vectors:
Vectors(U[j]);

Declare coframe:
Coframe(u[1]=d(zeta),u[2]=d(xi),u[3]=d(eta));

Declare frame:
Frame(U[j]);

The submersion

Declare mapping :

Mapping(pi,M,B,
        zeta=t,
        xi=r,
        eta=theta);

Let us see the attributes of the mapping:
Who(pi);

pi: mapping

Now we can calculate the projectors of the mapping:
P:=Projectors(pi);

V:=P[vertical];

H:=P[horizontal];

Where are we:
Domain();

Thus we are on the base manifold:

Jumping on the total manifold:
Domain(M);

Verify that is vertical vector:
'iota[E[4]](V)'=iota[E[4]](V);
'iota[E[4]](H)'=iota[E[4]](H);

Let us calculate invariants of the submersion:
Inv:=Invariants(pi):

The submersion is a riemannian one:
riemannianObstruction=Inv[riemannianObstruction];

The integrability obstruction is not equal to zero. Thus the corresponding horizontal distribution is not an intagrable one.
iO:=eval(Inv[integrabilityObstruction]);

Extraction of the field of mean curvature vectors of the fibers

N:=Inv[meanCurvature];

The mean curvature vectors are horizontal:
'iota[N](V)'=iota[N](V);
'iota[N](H)-N'=simplify(iota[N](H)-N);

The mean curvature vectors are projectable. Realy  where :
vol(F):=g(E[4],E[4]);

f:=ln(vol(F));

'-dual(d(f))/2-N'=simplify(-dual(d(f))/2-N);

Thus mean curvature  is basic vector field (horizontal and projectable).

The principal group   induces vector field  

Let us consider principal connection  of the fibration. It is easy to see that  

As soon as

'V'=V;

Then for principal connection we obtain:
Theta:=add(iota[iota[E[j]](V)](e[4])*e[j],j=1..4);

Now we can calculate the corresponding curvature of the fibration :

Omega:=collect(d(Theta),`&^`,factor);

For any horizontal vector fields X and Y we have . Thus we can construct the corresponding tensor directly:
AA:=-1/2*Omega&.E[4];

We can obtain the same tensor from integrability obstruction iO. To do this we redefine the table and use add procedure.

iO:=table(zero,antisymmetric,op(op(iO))[2]):
AB:=add(add((e[i]&^e[j])&.iO[i,j],i=1..j),j=1..4); 

Verify the identity:
AA-AB;